* do ~/Teaching/GetStart_stata/Version2/Program/lbw1_analysis.do

* Erstat flg linie med det directory som du gerne vil arbejde i
cd ~/Teaching/GetStart_stata/Version2/Program

clear
set mo off

* Erstat med navnet på den fil, hvor du har datasættet liggende
use ../../ISHR_dat/ishr/lbw1.dta

* Basal info om dato
d, d

**********************************************************************
* 2x2 tabel på sammenhæng mellem rygning og risiko for lav fødselsvægt
**********************************************************************
 
tab low smoke
tab low smoke, row

* Risk, RR (tværsnitsstudie)

cs low smoke

* OR (opfattet som case-control eller i sin egen ret)

cc low smoke

* Variabel med alderskategorier

recode age (0/19 = 1) (20/24 = 2) (25/29 = 3) (30/50 = 4), gen(agecat)

la var agecat "Mothers age (categorized)"
la de agelab 1 "-19yrs" 2 "20-24yrs" 3 "25-29yrs" 4 "30+yrs"
la val agecat agelab

sc age agecat, jitter(5)

* 2x2 tabel med OR for hver alderskategori

cc low smoke if agecat == 1 
cc low smoke if agecat == 2
cc low smoke if agecat == 3 
cc low smoke if agecat == 4 

* Eller det samme med et "loop"

forv i = 1/4 {
  cc low smoke if agecat == `i'
}

* Sidste aldersgruppe (grp 4) er for lille - tilføjer den til grp 3

recode agecat (4 = 3)

* Ændrer label - Bemærk: skal ikke igen "klistre" den på variabel med
* -label val-

la de agelab 3 "25+yrs" 4 " ", modify
codebook agecat

sc age agecat, jitter(5)

forv i = 1/3 {
  cc low smoke if agecat == `i'
}

* Mantel-Haentzel analyse med test for homogenitet af OR

mhodds low smoke, by(agecat)


**********************************************************************
* Analyse af fødselsvægt
**********************************************************************

* Stem-and-leaf "graf"

stem bwt
bys smoke: stem bwt

* Normalfordelt?

hist bwt, by(smoke) norm
qnorm bwt if smoke == 0
qnorm bwt if smoke == 1

* Ens varians

sdtest bwt, by(smoke)

* Ens middelværdi

ttest bwt, by(smoke)

* Stratificeret på aldersgrupper

bys agecat: ttest bwt, by(smoke)

* Ikke-parametrisk sammenligning

ranksum bwt, by(smoke)

* korrespondance mellem t-test og simpel regression

ttest bwt, by(smoke)
xi: regress bwt i.smoke

* kan nu lave robust regressionsanalyse uden antagelse af normalitet

xi: regress bwt i.smoke, robust